Fonction UNIQUE Excel : extraire une liste sans doublon

La fonction UNIQUE d'Excel renvoie la liste des valeurs distinctes d'une plage, sans jamais modifier les données d'origine. Sa syntaxe tient en une ligne : =UNIQUE(matrice).

Le résultat se propage automatiquement sur les cellules du dessous et se met à jour dès que la source change. Elle exige Excel 365, 2021 ou 2024 : sur 2016 et 2019, il faut passer par une alternative que nous détaillons plus bas.

Au sommaire :

• À quoi sert la fonction UNIQUE dans Excel ?

• Comment utiliser la fonction UNIQUE pas à pas

• Fonction UNIQUE sur plusieurs colonnes

• Fonction UNIQUE avec condition : la combiner à FILTRE

• Je n'ai pas la fonction UNIQUE : quelles versions d'Excel ?

• Équivalent et alternative à UNIQUE sur Excel 2016 et 2019

• Questions fréquentes sur la fonction UNIQUE

Téléchargez nos exercices sur la fonction UNIQUE Excel

fonction-unique-excel.xlsx

Télécharger XLSX • 50KB

À quoi sert la fonction UNIQUE dans Excel ?

La fonction UNIQUE permet d'extraire une liste sans doublon à partir d'une plage de données.

Elle conserve la première occurrence de chaque valeur et ignore automatiquement les suivantes.

La différence avec Données > Supprimer les doublons est importante :

• Supprimer les doublons efface directement les lignes en double dans votre tableau d'origine.

• UNIQUE ne modifie jamais vos données : elle crée simplement une nouvelle liste à côté.

  
  

Autre avantage majeur : le résultat de UNIQUE est dynamique. Si vous ajoutez une nouvelle valeur dans la source, la liste se met automatiquement à jour.

C'est pourquoi cette fonction est très utilisée pour créer des listes déroulantes intelligentes ou alimenter des tableaux de bord Excel.

La syntaxe complète de la fonction est la suivante :

=UNIQUE(matrice ; [par_col] ; [exactement_une_fois])

matrice (obligatoire) : la plage ou le tableau à dédoublonner.

par_col (facultatif) : FAUX ou omis, Excel compare les lignes entre elles. VRAI, il compare les colonnes entre elles.

exactement_une_fois (facultatif) : FAUX ou omis, vous obtenez toutes les valeurs distinctes. VRAI, vous n'obtenez que celles qui n'apparaissent qu'une seule fois.

C'est ce troisième argument qui piège le plus de monde en formation. Nos formateurs le résument ainsi : « distinct » et « apparaît une seule fois » ne veulent pas dire la même chose. Sur une liste contenant trois fois ETE26 et une fois VIP2026, la version par défaut renvoie les deux codes ; avec exactement_une_fois à VRAI, elle ne renvoie que VIP2026.

Exercice 4 : Donnée marketing : isoler les valeurs qui n'apparaissent qu'une fois

Objectif : sur un relevé de 15 utilisations de codes promo, retrouver les codes qui n'ont servi qu'à un seul client. C'est l'exercice 4 du classeur à télécharger : il ne se résout qu'avec le troisième argument.

Comment utiliser la fonction UNIQUE pas à pas

Prenons un carnet de commandes de 12 lignes, avec une colonne Client qui contient forcément des répétitions. L'objectif : obtenir la liste des clients distincts en une seule formule.

Étape 1 : Repérer la plage à dédoublonner

Sélectionnez uniquement la colonne concernée, sans l'en-tête, sinon le titre « Client » se retrouvera dans votre liste. Si vos données sont mises en forme de tableau structuré, utilisez plutôt la référence Tableau1[Client] : la plage s'étendra automatiquement à chaque nouvelle ligne saisie.

Étape 2 : Saisir la formule dans une cellule vide

Placez-vous dans une cellule qui dispose de place libre en dessous, puis saisissez :

=UNIQUE(C8:C19)

Validez avec Entrée. Inutile de recopier la formule vers le bas : une seule cellule contient la formule, et Excel se charge du reste.

Étape 3 : Vérifier la propagation

Un cadre bleu apparaît autour de tous les résultats : c'est la zone de propagation.

Toutes les cellules de cette zone dépendent de la formule UNIQUE située dans la première cellule (ici en jaune)

Si vous cliquez sur une cellule du résultat, Excel affiche la formule en grisé dans la barre de formule :

cela signifie qu'elle fait partie de la liste générée et qu'elle ne peut pas être modifiée seule.

Pour supprimer toute la liste, il suffit simplement d'effacer la première cellule contenant la formule. Excel supprimera automatiquement l'ensemble des résultats associés.

[

Exercice 1 : Donnée commerciale : la liste des clients sans doublon

Objectif : sortir la liste des clients distincts d'un carnet de commandes. La colonne des villes est déjà résolue dans le fichier pour vous servir de modèle.

Exercice 2 : Donnée financière : compter les valeurs distinctes

Objectif : savoir combien de fournisseurs différents ont été facturés sur le trimestre. On imbrique UNIQUE dans NBVAL : la liste intermédiaire n'apparaît nulle part, elle n'existe qu'à l'intérieur de la formule.

=NBVAL(UNIQUE(C25:C38))

Fonction UNIQUE sur plusieurs colonnes

Quand la plage passée à UNIQUE contient plusieurs colonnes, Excel ne compare plus les cellules une à une : il compare les lignes entières. Deux lignes ne sont écartées que si elles sont identiques sur toutes leurs colonnes.

=UNIQUE(C45:D56)

Sur un fichier RH, cela permet d'obtenir tous les couples Service + Poste réellement présents dans l'effectif. Finance / Comptable et Finance / Contrôleur de gestion sont bien conservés tous les deux, car les lignes diffèrent. Le résultat se propage alors sur deux colonnes.

Exercice 3 : Donnée RH : dédoublonner sur deux colonnes à la fois

Objectif : lister les couples Service + Poste distincts d'un effectif de 12 salariés, en une seule formule renvoyant deux colonnes.

Le deuxième argument, par_col, sert lui à un cas plus rare mais qui bloque net quand on tombe dessus : des données saisies horizontalement. Un planning où chaque jalon occupe une colonne, par exemple. À VRAI, UNIQUE compare les colonnes entre elles et propage son résultat vers la droite.

=UNIQUE(B84:K84 ; VRAI)

Exercice 5 : Gestion de projet : des données saisies en ligne

Objectif : lister les intervenants distincts d'un planning dont les affectations sont saisies sur une seule ligne. Sans le deuxième argument, la formule renvoie la ligne telle quelle, doublons compris.

Fonction UNIQUE avec condition : la combiner à FILTRE

UNIQUE ne sait pas filtrer. Il n'existe aucun argument « critère » dans sa syntaxe, et c'est une demande qui revient à chaque session de formation. La solution consiste à lui fournir directement le bon sous-ensemble, en l'emboîtant avec la fonction FILTRE :

=UNIQUE(FILTRE(B94:B109 ; C94:C109 = H94))

L'ordre compte. FILTRE s'exécute en premier et ne garde que les lignes de la région recherchée ; UNIQUE dédoublonne ensuite ce résultat. Écrire l'inverse dédoublonnerait d'abord toute la base, puis tenterait de filtrer une liste qui n'a plus la même hauteur que la colonne de critères, et renverrait une erreur.

En plaçant le critère dans une cellule plutôt qu'en dur dans la formule, vous obtenez une liste qui se recalcule à chaque changement de région. C'est exactement le mécanisme derrière une liste déroulante dépendante d'une autre.

Exercice 6 : Donnée commerciale : les clients uniques d'une seule région

Objectif : obtenir la liste sans doublon des clients d'Occitanie à partir d'un fichier de 16 ventes multi-régions. C'est l'exercice le plus difficile du classeur.

À noter : si vous cherchez seulement à afficher temporairement un sous-ensemble sans créer de nouvelle liste, le filtre automatique reste plus rapide.

Je n'ai pas la fonction UNIQUE : quelles versions d'Excel ?

C'est de loin le problème le plus signalé sur cette fonction. Dans neuf cas sur dix, il ne s'agit pas d'un bug mais d'une question de version. UNIQUE fait partie des fonctions matricielles dynamiques, arrivées avec le moteur de calcul introduit en 2020.

• Microsoft 365, Excel 2021, Excel 2024 et Excel pour le web : la fonction est disponible.

• Excel 2019, 2016, 2013 et versions antérieures : la fonction n'existe pas et n'arrivera jamais. Ces licences perpétuelles sont figées à leur date de sortie.

• Office LTSC 2021 : cas particulier signalé plusieurs fois. La fonction devrait être là, mais une installation par-dessus une version 2016 ou 2019 mal désinstallée laisse parfois l'ancien jeu de fonctions actif. Une réparation d'Office depuis Panneau de configuration > Programmes règle généralement le problème.

Autre symptôme classique : vous ouvrez un fichier reçu d'un collègue et les cellules affichent #NOM?, parfois avec une formule qui ressemble à =_xlfn.UNIQUE(A2:A20). Ce préfixe _xlfn. est la signature d'une fonction qu'Excel connaît de nom mais ne sait pas exécuter dans votre version. Le fichier n'est pas corrompu : les formules seront de nouveau calculées si vous l'ouvrez avec une version compatible, ou dans Excel pour le web, gratuit avec un compte Microsoft.

Ne confondez pas non plus cette erreur avec #PROPAGATION, qui signifie l'inverse : votre version connaît bien UNIQUE, mais quelque chose bloque la zone où le résultat doit s'étendre. Un tableau de bord complet sur les erreurs Excel et la fonction SIERREUR vous aidera à les distinguer.

Équivalent et alternative à UNIQUE sur Excel 2016 et 2019

Pas de fonction UNIQUE dans votre version ? Trois solutions existent, de la plus souple à la plus rapide.

La formule matricielle INDEX + EQUIV + NB.SI

C'est le seul équivalent qui reste dynamique. On saisit la formule dans la première cellule, on valide avec Ctrl + Maj + Entrée, puis on recopie vers le bas sur une hauteur suffisante :

=INDEX($C$8:$C$19 ; EQUIV(0 ; NB.SI($G$7:G7 ; $C$8:$C$19) ; 0))

Le principe : NB.SI compte combien de fois chaque valeur de la source figure déjà dans la liste en construction juste au-dessus. EQUIV repère la première valeur dont ce compte vaut zéro, autrement dit la première valeur pas encore extraite, et INDEX la renvoie. Une fois toutes les valeurs sorties, la formule affiche #N/A : entourez-la de SIERREUR pour obtenir des cellules vides.

Prévoyez large sur la recopie, mais pas trop : c'est une formule matricielle recopiée sur chaque ligne, elle ralentit sensiblement un classeur au-delà de quelques milliers de lignes.

L'outil Supprimer les doublons

Données > Supprimer les doublons donne le même résultat en trois clics, mais de façon figée et destructive. Travaillez toujours sur une copie de la colonne. La marche à suivre détaillée figure dans notre article supprimer les doublons sur Excel.

Le tableau croisé dynamique

Souvent oublié, c'est pourtant l'alternative la plus confortable pour un gros volume : placez le champ à dédoublonner en ligne, et le tableau croisé dynamique affiche la liste des valeurs distinctes, avec leur nombre d'occurrences en prime. Un clic sur Actualiser suffit pour le mettre à jour. Pour un traitement récurrent sur des fichiers externes, Power Query et son bouton Supprimer les doublons resteront le choix le plus robuste.

Questions fréquentes sur la fonction UNIQUE

La fonction UNIQUE existe-t-elle en français ?

Oui, et c'est une source de confusion fréquente : elle porte exactement le même nom en français et en anglais. Contrairement à SOMME/SUM ou RECHERCHEV/VLOOKUP, il n'y a rien à traduire. Seuls changent le séparateur d'arguments (point-virgule en français, virgule en anglais) et le nom affiché des arguments : par_col pour by_col, exactement_une_fois pour exactly_once.

Comment compter les valeurs uniques sans afficher la liste ?

En imbriquant UNIQUE dans NBVAL : =NBVAL(UNIQUE(A2:A100)). La liste intermédiaire n'occupe aucune cellule. Sur une version sans UNIQUE, l'équivalent historique est =SOMMEPROD(1/NB.SI(A2:A100;A2:A100)), qui échoue toutefois si la plage contient des cellules vides.

Comment trier le résultat de la fonction UNIQUE ?

En l'emboîtant dans TRIER : =TRIER(UNIQUE(A2:A100)). La liste sort alors dédoublonnée et classée par ordre alphabétique. Sans cette imbrication, UNIQUE respecte l'ordre d'apparition dans la source. Voir aussi notre article sur comment trier par ordre alphabétique sur Excel.

Pourquoi ma formule renvoie-t-elle #PROPAGATION ?

Parce qu'une cellule occupée se trouve dans la zone où le résultat doit s'étendre. Excel surligne la zone bloquée : videz-la, ou déplacez votre formule dans une colonne libre. Cette erreur apparaît aussi quand on saisit une formule matricielle dynamique à l'intérieur d'un tableau structuré, qui n'accepte pas la propagation.

Peut-on utiliser UNIQUE avec RECHERCHEV ?

Oui, et c'est un usage très courant : on construit d'abord la liste des identifiants distincts avec UNIQUE, puis on va chercher les informations associées avec RECHERCHEV ou, plus confortablement, avec RECHERCHEX. Le tableau de synthèse se construit alors tout seul à mesure que la base s'enrichit.

Envie de valider votre niveau sur ce type de fonctions ? Notre test Excel gratuit avec correction en ligne vous situe en quelques minutes. Et si les fonctions matricielles dynamiques vous intéressent au-delà de UNIQUE, elles occupent une bonne place dans notre formation Excel avancé. Vous trouverez également tous nos exercices Excel corrigés en accès libre.